OracleでBLOBからファイルを取得する方法は？

このチュートリアルでは、OracleのBLOB列からファイルを取得する方法を学習します。例を挙げると、OracleでテーブルEXT_FILESを作成しました。これは、テーブルの構造です。

CREATE TABLE EXT_FILES
(
FILE_NAME VARCHAR2(1000 BYTE),
FILE_CONTENT BLOB
)
/

上記の表にデータを挿入します。 BLOB列にファイルを挿入する方法がわからない場合は、次の記事「OracleテーブルのBLOB列にファイルを挿入する方法」を確認してください。

BLOB列からディスクにファイルを取得するには、スキーマにOracleディレクトリオブジェクトを作成する必要があります。 Oracleでディレクトリを作成するには、次のコマンドを実行します。

CREATE OR REPLACE DIRECTORY IMGDIR AS 'C:\TEMP\IMAGES';

以下は、カーソルを使用してEXT_FILESテーブル（BLOBデータを含む）からレコードをフェッチし、指定されたディレクトリにファイルを1つずつ抽出するOracleストアドプロシージャの例です。

OracleのBLOB列からファイルを取得するためのOracleストアドプロシージャの例

CREATE OR REPLACE PROCEDURE get_files_from_blob
IS
l_file UTL_FILE.file_type;
l_buffer RAW (32767);
l_amount BINARY_INTEGER := 32767;
l_pos INTEGER := 1;
l_blob_len INTEGER;
l_blob BLOB;
l_filename ext_files.file_name%TYPE;
/* cursor to get the records from the table */
CURSOR c_files
IS
SELECT file_name, file_content FROM ext_files;
BEGIN
OPEN c_files;

LOOP

FETCH c_files
INTO l_filename, l_blob;

EXIT WHEN c_files%NOTFOUND;

l_blob_len := DBMS_LOB.getlength (l_blob);

/* Change the directory name (IMGDIR) to your Oracle directory object name*/
l_file :=
UTL_FILE.fopen ('IMGDIR',
l_filename,
'wb',
32767);
l_pos := 1;

WHILE l_pos < l_blob_len
LOOP
DBMS_LOB.read (l_blob,
l_amount,
l_pos,
l_buffer);
UTL_FILE.put_raw (l_file, l_buffer, TRUE);
l_pos := l_pos + l_amount;
END LOOP;

UTL_FILE.fclose (l_file);
END LOOP;

CLOSE c_files;
EXCEPTION
WHEN OTHERS
THEN
IF UTL_FILE.is_open (l_file)
THEN
UTL_FILE.fclose (l_file);
END IF;

RAISE;
END;

テスト

BEGIN
get_files_from_blob;
END;
/

出力

PL/SQL procedure successfully completed.

これで、抽出されたファイルのIMGDIRディレクトリオブジェクトの場所を確認できます。

OracleでBLOBからファイルを取得する方法は？

OracleのBLOB列からファイルを取得するためのOracleストアドプロシージャの例

テスト

出力

関連項目：