PL / SQLでBLOBをファイルとして保存する方法は？

ここでは、BLOBデータをファイルとしてPL/SQLに保存する例を示します。 BLOBデータは、BLOB列を持つテーブルから取得することも、ディスク上のファイルから取得することもできます。

BLOBをファイルとして保存するためのPL/SQL関数の例

以下の手順では、次の3つの引数を取ります。

1. Oracle Directoryオブジェクト名（i_dirとして）。
2. ファイル名として（i_fileとして）保存します。
3. BLOBデータ（i_blobとして）。

CREATE OR REPLACE PROCEDURE blob_to_file (i_dir    IN VARCHAR2,
                                          i_file   IN VARCHAR2,
                                          i_blob   IN BLOB)
AS
   l_file       UTL_FILE.file_type;
   l_buffer     RAW (32767);
   l_amount     BINARY_INTEGER := 32767;
   l_pos        INTEGER := 1;
   l_blob_len   INTEGER;
BEGIN
   l_blob_len := DBMS_LOB.getlength (i_blob);

   l_file :=
      UTL_FILE.fopen (i_dir,
                      i_file,
                      'WB',
                      32767);

   WHILE l_pos < l_blob_len
   LOOP
      DBMS_LOB.read (i_blob,
                     l_amount,
                     l_pos,
                     l_buffer);
      UTL_FILE.put_raw (l_file, l_buffer, TRUE);
      l_pos := l_pos + l_amount;
   END LOOP;

   UTL_FILE.fclose (l_file);
EXCEPTION
   WHEN OTHERS
   THEN
      IF UTL_FILE.is_open (l_file)
      THEN
         UTL_FILE.fclose (l_file);
      END IF;

      RAISE;
END blob_to_file;

テスト

次のPL/SQLブロックは、Oracleディレクトリ・オブジェクト、ファイル名、およびBLOBデータを渡すことにより、上記のプロシージャを呼び出します。 BLOBデータには、以前のブログ投稿で例を示したGET_BLOB関数を使用しています。PL/SQLのファイルからBLOBを取得します。以下の場合、MY_DIRの場所にあるファイルmyfile.jpgからBLOBデータを取得し、IMG_DIRの場所にあるファイルabc.jpgに保存します。

DECLARE
   f_blob   BLOB;
BEGIN
   /* check the above mentioned link for get_blob function example */
   f_blob := get_blob ('MY_DIR', 'myfile.jpg');
   /* now pass the blob to blob_to_file procedure to save it as a file */
   blob_to_file ('IMG_DIR', 'abc.jpg', f_blob);
END;

これで、BLOBを介して作成されたファイルのIMG_DIRディレクトリの場所を確認できます。

関連項目：

• Oracle Directoryオブジェクトを作成するにはどうすればよいですか？
• Toadを使用してOracleテーブルからBLOBデータを抽出する方法を学ぶ